Arduino Project

Arduino Automatic Light Switch with Servo Motor

Kit purchase

Looking for parts? Check out our all-in-one kits below — packed with components, beginner-friendly guides, and tons of fun.

2.webp__PID:7d088a16-8752-49fb-8b1f-f9bba7297987

Name	Includes Arduino board	PURCHASE LINK
Elite Explorer Kit	Arduino Uno R4 WiFi	BUY
3 in 1 Ultimate Starter Kit	Arduino Uno R4 Minima	BUY
Ultimate Sensor Kit	Arduino Uno R4 Minima	BUY
Universal Maker Sensor Kit	×	BUY

Course Introduction

In this lesson, you will learn how to use Arduino along with servo motor, buttons, LED, and resistor to create a light play game.

Pressing the button to start.

Note

If this is your first time working with an Arduino project, we recommend downloading and reviewing the basic materials first.

1.1 Install Arduino IDE(Important)
1.2 Introduction of Arduino IDE

Required Components

In this project, we need the following components:

SN	COMPONENT INTRODUCTION	QUANTITY	PURCHASE LINK
1	Arduino UNO R4 Minima/Arduino UNO R4 WIFI	1	BUY
2	USB Type-C cable	1	×
3	Breadboard	1	BUY
4	Wires	Several	BUY
5	220Ω resistor	1	BUY
6	Button	2	BUY
7	LED	1	BUY
8	Digital Servo Motor	1	BUY

Wiring

4.webp__PID:ad5135a3-d3a0-4d5d-81d7-9e7cbfe7b915

Common Connections:

LED
Connect the LED cathode to the negative power bus on the breadboard, and the LED anode to a 1kΩ resistor then to 5 on the Arduino.

Button-ON
Connect to breadboard’s negative power bus.
Connect to 2 on the Arduino.

Button-OFF
Connect to breadboard’s negative power bus.
Connect to 3 on the Arduino.

Digital Servo Motor
Connect to breadboard’s positive power bus.
Connect to breadboard’s negative power bus.
Connect to 9 on the Arduino.

Writing the Code

Note
You can copy this code into Arduino IDE.
Don’t forget to select the board(Arduino UNO R4 Minima/Minima) and the correct port before clicking the Upload button.

  #include <Servo.h>

// Pins
const int BUTTON_ON_PIN = 2;
const int BUTTON_OFF_PIN = 3;
const int LED_PIN = 5;
const int SERVO_PIN = 9;

// Servo angles
const int SERVO_HOME_ANGLE = 0;
const int SERVO_PRESS_ANGLE = 30;

// Timing
const unsigned long WAIT_BEFORE_PRESS = 2000;
const unsigned long SERVO_PRESS_TIME = 600;
const unsigned long DEBOUNCE_DELAY = 200;

Servo switchServo;

bool lightOn = false;
bool servoTriggered = false;

bool lastButtonOnState = HIGH;
bool lastButtonOffState = HIGH;

unsigned long lightOnTime = 0;
unsigned long lastButtonOnTime = 0;
unsigned long lastButtonOffTime = 0;

void setup() {
  pinMode(BUTTON_ON_PIN, INPUT_PULLUP);
  pinMode(BUTTON_OFF_PIN, INPUT_PULLUP);
  pinMode(LED_PIN, OUTPUT);

  switchServo.attach(SERVO_PIN);
  switchServo.write(SERVO_HOME_ANGLE);

  digitalWrite(LED_PIN, LOW);
}

void loop() {
  handleButtons();

  if (lightOn && !servoTriggered) {
    if (millis() - lightOnTime >= WAIT_BEFORE_PRESS) {
      pressOffButton();
      servoTriggered = true;
    }
  }
}

void handleButtons() {
  bool currentButtonOnState = digitalRead(BUTTON_ON_PIN);
  bool currentButtonOffState = digitalRead(BUTTON_OFF_PIN);
  unsigned long now = millis();

  if (lastButtonOnState == HIGH && currentButtonOnState == LOW) {
    if (now - lastButtonOnTime > DEBOUNCE_DELAY) {
      lightOn = true;
      servoTriggered = false;
      lightOnTime = now;
      digitalWrite(LED_PIN, HIGH);
      lastButtonOnTime = now;
    }
  }

  if (lastButtonOffState == HIGH && currentButtonOffState == LOW) {
    if (now - lastButtonOffTime > DEBOUNCE_DELAY) {
      lightOn = false;
      digitalWrite(LED_PIN, LOW);
      switchServo.write(SERVO_HOME_ANGLE);
      lastButtonOffTime = now;
    }
  }

  lastButtonOnState = currentButtonOnState;
  lastButtonOffState = currentButtonOffState;
}

void pressOffButton() {
  switchServo.write(SERVO_PRESS_ANGLE);
  delay(SERVO_PRESS_TIME);

  if (digitalRead(BUTTON_OFF_PIN) == LOW) {
    lightOn = false;
    digitalWrite(LED_PIN, LOW);
  }

  switchServo.write(SERVO_HOME_ANGLE);
}

Recover password

Create my account

Arduino Project

Arduino Automatic Light Switch with Servo Motor

Kit purchase

Course Introduction

Required Components

Wiring

Common Connections:

Writing the Code

Arduino Project

Arduino Automatic Light Switch with Servo Motor

Kit purchase

Course Introduction

Required Components

Wiring

Common Connections:

Writing the Code

Subscribe to our newsletter