Arduino Project
Barrier Gate 4.0
Course Introduction
This project uses an ultrasonic sensor, traffic lights, a servo, and a buzzer to create an automatic gate system.
When a car is detected, the lights change, the gate opens, and the buzzer signals. After the car passes, the gate closes and the red light turns back on.
Note
If this is your first time working with an Arduino project, we recommend downloading and reviewing the basic materials first.
1.1 Install Arduino IDE(Important)
1.2 Introduction of Arduino IDE
Required Components
In this project, we need the following components:
Wiring
Common Connections:
Traffic light LED
R: Connect to 7 on the Arduino.
Y: Connect to 6 on the Arduino.
G: Connect to 5 on the Arduino.
GND: Connect to breadboard’s negative power bus.
Digital Servo Motor
Connect to breadboard’s positive power bus.
Connect to breadboard’s negative power bus.
Connect to 3 on the Arduino.
Ultrasonic Sensor Module
Trig: Connect to 11 on the Arduino.
Echo: Connect to 10 on the Arduino.
GND: Connect to breadboard’s negative power bus.
VCC: Connect to breadboard’s red power bus.
Buzzer Module
I/0: Connect to 2 on the Arduino.
＋: Connect to breadboard’s red power bus.
－: Connect to breadboard’s negative power bus.
Writing the Code
Note
You can copy this code into Arduino IDE.
Don’t forget to select the board(Arduino UNO R4 WIFI) and the correct port before clicking the Upload button.
#include
// Ultrasonic sensor pins
const int trigPin = 11;
const int echoPin = 10;
// Traffic light pins
const int redPin = 7;
const int yellowPin = 6;
const int greenPin = 5;
// Servo and buzzer pins
const int servoPin = 3;
const int buzzerPin = 2;
Servo myServo;
// Play one beep
void beepOnce(int freq, int dur) {
tone(buzzerPin, freq, dur);
delay(dur * 1.2);
noTone(buzzerPin);
}
// Play three short beeps
void beepTriple() {
for (int i = 0; i < 3; i++) {
tone(buzzerPin, 1500, 120);
delay(150);
noTone(buzzerPin);
delay(80);
}
}
// Smoothly open the gate
void openGate() {
for (int pos = 0; pos <= 90; pos++) {
myServo.write(pos);
delay(10); // smooth speed
}
}
// Smoothly close the gate
void closeGate() {
for (int pos = 90; pos >= 0; pos--) {
myServo.write(pos);
delay(10);
}
}
// Read distance once
float getDistance() {
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH);
delayMicroseconds(10);
digitalWrite(trigPin, LOW);
long duration = pulseIn(echoPin, HIGH, 25000); // 25ms timeout
if (duration == 0) return 999; // no echo
return duration * 0.034 / 2;
}
void setup() {
Serial.begin(9600);
pinMode(trigPin, OUTPUT);
pinMode(echoPin, INPUT);
pinMode(redPin, OUTPUT);
pinMode(yellowPin, OUTPUT);
pinMode(greenPin, OUTPUT);
pinMode(buzzerPin, OUTPUT);
myServo.attach(servoPin);
myServo.write(0); // gate starts closed
digitalWrite(redPin, HIGH); // red ON at start
}
void loop() {
float distance = getDistance();
Serial.print("Distance: ");
Serial.println(distance);
// Car detected
if (distance < 10) {
// Yellow + warning beep
digitalWrite(redPin, LOW);
digitalWrite(yellowPin, HIGH);
digitalWrite(greenPin, LOW);
beepOnce(1000, 300);
delay(1000);
// Green light + open gate
digitalWrite(yellowPin, LOW);
digitalWrite(greenPin, HIGH);
openGate(); // smooth motion (no ultrasonic during movement)
beepTriple(); // pass signal
delay(1500);
// Red light + close gate
digitalWrite(greenPin, LOW);
digitalWrite(redPin, HIGH);
closeGate(); // smooth motion
beepOnce(800, 200);
delay(500);
}
delay(200); // small delay between checks
}