#include 
#include 

#define ID_LEN 4   // RFID UID length

// Hardware pins
const int servoPin  = 9;    // Servo for door control
const int buzzerPin = 10;   // Buzzer for sound feedback
const int flamePin  = 11;   // Flame sensor (digital)
const int smokePin  = A0;   // Smoke sensor (analog)

// Objects
RFID1 rfid;
Servo myServo;

// Authorized RFID card UID
uchar userId[ID_LEN] = {0x33, 0xF8, 0xB8, 0x1A};
uchar userIdRead[ID_LEN];

// Servo position control (smooth movement)
int targetPos  = 0;
int currentPos = 0;

// Door action state (opened by RFID)
bool cardAction = false;
unsigned long cardTimer = 0;

// Emergency state (smoke or flame)
bool emergencyAlert = false;
bool emergencyRecovering = false;
unsigned long emergencyRecoverStart = 0;

// Smoke sensor threshold
int smokeValue = 0;
const int smokeThreshold = 200;

// Set the target angle for the servo
// The servo will move to this angle smoothly
void setServoAngle(int angle) {
  targetPos = constrain(angle, 0, 90);
}

// Move the servo step by step without blocking the program
void servoSmoothRun() {
  static unsigned long lastStep = 0;

  if (millis() - lastStep >= 15) {
    lastStep = millis();

    if (currentPos < targetPos) currentPos++;
    else if (currentPos > targetPos) currentPos--;

    myServo.write(currentPos);
  }
}

// Short beep for access granted
void beepShort() {
  tone(buzzerPin, 2000);
  delay(80);
  noTone(buzzerPin);
}

// Beep pattern for access denied
void beepDenied() {
  for (int i = 0; i < 4; i++) {
    tone(buzzerPin, 1600);
    delay(100);
    noTone(buzzerPin);
    delay(100);
  }
}

// Continuous alarm sound without delay
void beepAlarmNonBlock() {
  static unsigned long t = 0;
  static bool buz = false;

  if (millis() - t > 120) {
    t = millis();
    buz = !buz;
    if (buz) tone(buzzerPin, 1500);
    else noTone(buzzerPin);
  }
}

// Read RFID card UID
void getId() {
  uchar status, str[MAX_LEN];
  status = rfid.anticoll(str);

  if (status == MI_OK) {
    for (int i = 0; i < ID_LEN; i++) {
      userIdRead[i] = str[i];
    }
    rfid.halt();
  }
}

// Check if the scanned card is authorized
bool idVerify() {
  for (int i = 0; i < ID_LEN; i++) {
    if (userIdRead[i] != userId[i]) return false;
  }
  return true;
}

// Clear UID buffer after each scan
void clearBuffer() {
  for (int i = 0; i < ID_LEN; i++) {
    userIdRead[i] = 0;
  }
}

void setup() {
  // Initialize RFID module (library-specific pins)
  rfid.begin(7, 5, 4, 3, 6, 2);
  rfid.init();

  pinMode(buzzerPin, OUTPUT);
  pinMode(flamePin, INPUT);

  // Initialize servo (door closed)
  myServo.attach(servoPin);
  myServo.write(0);
  currentPos = 0;
  targetPos  = 0;
}

void loop() {
  // Read sensors
  smokeValue = analogRead(smokePin);
  bool flameDetected = (digitalRead(flamePin) == LOW);

  bool emergencyDetected =
    (smokeValue > smokeThreshold) || flameDetected;

  bool allowRFID = true;

  // Emergency logic: force door open
  if (emergencyDetected) {
    emergencyAlert = true;
    emergencyRecovering = false;

    setServoAngle(90);
    beepAlarmNonBlock();
    allowRFID = false;
  }
  else {
    // Wait for emergency to fully clear before closing the door
    if (emergencyAlert) {
      if (!emergencyRecovering) {
        emergencyRecovering = true;
        emergencyRecoverStart = millis();
      }

      if (millis() - emergencyRecoverStart < 1500) {
        beepAlarmNonBlock();
        allowRFID = false;
      }
      else {
        emergencyAlert = false;
        emergencyRecovering = false;

        setServoAngle(0);
        noTone(buzzerPin);
        allowRFID = true;
      }
    }
  }

  // RFID access control
  if (allowRFID && !cardAction) {
    uchar status, str[MAX_LEN];
    status = rfid.request(PICC_REQIDL, str);

    if (status == MI_OK) {
      getId();

      if (idVerify()) {
        beepShort();
        setServoAngle(90);
        cardAction = true;
        cardTimer = 0;
      }
      else {
        beepDenied();
      }

      clearBuffer();
    }
  }

  // Auto close door after RFID access
  if (cardAction) {
    if (currentPos >= 90) {
      if (cardTimer == 0) cardTimer = millis();
      if (millis() - cardTimer >= 1500) {
        setServoAngle(0);
      }
    }

    if (currentPos <= 3 && targetPos == 0) {
      cardAction = false;
      cardTimer = 0;
    }
  }

  servoSmoothRun();
}