Arduino Project

Stair Light

Course Introduction

In this lesson, you’ll use a PIR motion sensor, an LED, and a button with the Arduino R4 UNO to build a smart lighting system with three operating modes.

The system can automatically turn on the LED when motion is detected, keep it always on, or keep it always off. A single button toggles between these modes, and the LED behavior updates accordingly.

Note

If this is your first time working with an Arduino project, we recommend downloading and reviewing the basic materials first.

1.1 Install Arduino IDE(Important)
1.2 Introduction of Arduino IDE

Required Components

In this project, we need the following components:

SN

COMPONENT INTRODUCTION

QUANTITY

PURCHASE LINK

1

Arduino UNO R4 Minima

1

BUY

2

USB Type-C cable

1

×

3

Breadboard

1

BUY

4

Wires

Several

BUY

5

Button

1

BUY

6

LED

1

BUY

7

1kΩ resistor

1

BUY

Wiring

stair_light_bb.webp__PID:4f0a4bbe-6590-4e10-9f8f-d5d30eb78021

Common Connections:

LED
Connect the LED cathode to the to a 220Ω resistor, then to negative power bus on the breadboard, anode to 3 on the Arduino.

PIR
＋: Connect to 2 on the Arduino.
－: Connect to breadboard’s negative power bus.

Button
Connect to the breadboard’s negative power bus, and the other end to 4 on the Arduino board.

Writing the Code

Note
You can copy this code into the Arduino IDE.
Don’t forget to select the board(Arduino UNO R4 Minima) and the correct port before clicking the Upload button.


const int PIR_PIN = 2;    // PIR motion sensor signal pin
const int LED_PIN = 3;    // LED pin
const int BUTTON_PIN = 4; // Button pin

int mode = 0;  // 0 = Auto, 1 = Always ON, 2 = Always OFF
bool lastButtonState = HIGH;
unsigned long lastMotionTime = 0;
const unsigned long LIGHT_DELAY = 3000; // 3s delay

void setup() {
  pinMode(PIR_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP); // Internal pull-up

  digitalWrite(LED_PIN, LOW);
  Serial.begin(9600);
  Serial.println("Mode 0: Auto, Mode 1: Always ON, Mode 2: Always OFF");
}

void loop() {
  // ---- Button detection (toggle between modes) ----
  bool buttonState = digitalRead(BUTTON_PIN);
  if (buttonState == LOW && lastButtonState == HIGH) {
    mode = (mode + 1) % 3;  // Cycle through 0->1->2->0
    Serial.print("Mode: ");
    if (mode == 0) Serial.println("Auto");
    else if (mode == 1) Serial.println("Always ON");
    else Serial.println("Always OFF");
    delay(200); // Debounce
  }
  lastButtonState = buttonState;

  // ---- Mode control ----
  if (mode == 1) {
    // Always ON
    digitalWrite(LED_PIN, HIGH);
  } else if (mode == 2) {
    // Always OFF
    digitalWrite(LED_PIN, LOW);
  } else {
    // Auto mode (PIR control)
    int motion = digitalRead(PIR_PIN);
    if (motion == HIGH) {
      digitalWrite(LED_PIN, HIGH);
      lastMotionTime = millis(); // Record time when motion detected
    } else if (millis() - lastMotionTime > LIGHT_DELAY) {
      digitalWrite(LED_PIN, LOW);
    }
  }
}